Abap write statement/command example in sap abap

Execute this program below and check you will understand different ways to use the write statement.

REPORT demo_write_statement.

DATA: number TYPE p VALUE '-1234567.89' DECIMALS 2,
      len TYPE i,
      pos TYPE i,
      text(10) TYPE c VALUE '1234567890',
      integer TYPE i VALUE  1234567890,
      g(5) TYPE c VALUE 'Hello', f(5) TYPE c VALUE 'Dolly',
      time TYPE t VALUE '154633',
      float TYPE f VALUE '123456789.0',
      pack TYPE p VALUE '123.456' DECIMALS 3,
      flag1 TYPE c    VALUE ' ',
      flag2 TYPE c    VALUE 'X',
      flag3(5) TYPE c VALUE 'Xenon'.

* simple WRITE statement

WRITE 'Hello, here I am!'.

SKIP 2.

* standard output format

WRITE:  'Number', number, 'is packed'.

SKIP 2.

* positioning

WRITE 'First line.'.
WRITE 'Still first line.'.
WRITE /'Second line.'.
WRITE /13 'Third line.'.

SKIP 2.

len = 10.
pos = 13.
WRITE 'The string ------------ appears in the text.'.
WRITE AT pos(len) text.

SKIP 2.

* cutting

WRITE: (5) integer, /(5) text.

SKIP 2.

* no empty lines in lists

WRITE:   'One',
       / '   ',
       / 'Two'.

SKIP 2.

* formatting

WRITE: g, f.
WRITE: /10 g,
       /   f UNDER g.
WRITE: / g NO-GAP, f.

SKIP 2.

WRITE: time,
  /(8) time USING EDIT MASK '__:__:__'.

SKIP 2.

WRITE: '000123',
     / '000123' NO-ZERO.

SKIP 2.

WRITE float EXPONENT 3.

SKIP 2.

WRITE pack DECIMALS 2.

SKIP 2.

WRITE: / pack ROUND -2,
       / pack ROUND -1,
       / pack ROUND 1,
       / pack ROUND 2.

SKIP 2.

WRITE: sy-datum,
     / sy-datum YYMMDD.

SKIP 2.

* icons and symbols

INCLUDE <symbol>.
INCLUDE <icon>.
WRITE: /  'Telephone symbol:', sym_phone AS SYMBOL.
SKIP.
WRITE: /  'Alarm icon:   ', icon_alarm AS ICON.

SKIP 2.

* checkboxes

WRITE: / 'Flag 1 ', flag1  AS CHECKBOX,
       / 'Flag 2 ', flag2  AS CHECKBOX,
       / 'Flag 3 ', flag3  AS CHECKBOX.